CraftTweaker/settings.gradle.kts at 1.21.1 · Dreamfinity/CraftTweaker · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
import java.io.FileFilter

pluginManagement {
    repositories {
        gradlePluginPortal()
        mavenCentral()
        exclusiveContent {
            forRepository {
                maven("https://maven.fabricmc.net") {
                    name = "Fabric"
                }
            }
            filter {
                includeGroup("net.fabricmc")
                includeGroup("fabric-loom")
            }
        }
        maven("https://maven.neoforged.net/releases") {
            content {
//                includeModule("net.neoforged.moddev", "net.neoforged.moddev.gradle.plugin")
//                includeModule("net.neoforged.moddev.junit", "net.neoforged.moddev.junit.gradle.plugin")
                includeGroupAndSubgroups("net.neoforged")
            }
        }
        exclusiveContent {
            forRepository {
                maven("https://repo.spongepowered.org/repository/maven-public") {
                    name = "Sponge"
                }
            }
            filter {
                includeGroupAndSubgroups("org.spongepowered")
            }
        }
        exclusiveContent {
            forRepository {
                maven("https://maven.minecraftforge.net") {
                    name = "Forge"
                }
            }
            filter {
                includeGroup("net.minecraftforge")
            }
        }
        exclusiveContent {
            forRepository {
                maven("https://maven.parchmentmc.org") {
                    name = "ParchmentMC"
                }
            }
            filter {
                includeGroup("org.parchmentmc.data")
            }
        }

        exclusiveContent {
            forRepository {
                maven("https://maven.blamejared.com") {
                    name = "BlameJared"
                }
            }
            filter {
                includeGroupAndSubgroups("com.blamejared")
                includeGroupAndSubgroups("net.darkhax")
            }
        }

    }
}

plugins {
    id("org.gradle.toolchains.foojay-resolver-convention") version "0.8.0"
}

rootProject.name = "CraftTweaker"
val excludedProjects = setOf(
        "buildSrc",
        "ModuleDeserializer",
        "ModuleSerializationShared",
        "ModuleSerializer",
        "JavaSource",
        "JavaSourceCompiler",
        "IDE",
        "Constructor",
        "DrawableGui",
        "DrawableGuiIconConverter",
        "CompilerShared"
)

include("ZenCode")
collectSubProjects("ZenCode")

include("common")
include("fabric")
//include("forge")
include("neoforge")

if (file("CraftTweaker-Annotation-Processors").exists()) {
    includeBuild("CraftTweaker-Annotation-Processors") {
        dependencySubstitution {
            substitute(module("com.blamejared.crafttweaker:Crafttweaker_Annotation_Processors")).using(project(":"))
        }
    }
}

fun collectSubProjects(folder: String) {

    file(folder).listFiles(FileFilter {

        if (!it.isDirectory || excludedProjects.contains(it.name)) {
            return@FileFilter false
        }

        return@FileFilter File(it, "build.gradle").isFile || File(it, "build.gradle.kts").isFile
    })?.forEach {
        include(":${it.name}")
        project(":${it.name}").projectDir = File("./$folder/" + it.name)
    }
}