fireblanket/build.gradle at fabric-26.1 · ModFest/fireblanket · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
//file:noinspection GroovyAssignabilityCheck
//file:noinspection GroovyAccessibility
plugins {
	id "maven-publish"
	alias libs.plugins.loom
}

version = "$baseVersion+$branch"

base {
	archivesName = project.slug
}

repositories {
	maven { url = "https://api.modrinth.com/maven" }
	maven { url = "https://maven.enginehub.org/repo/" }
	maven { url = "https://maven.gegy.dev/releases/" }
	maven { url = "https://maven.bawnorton.com/releases" }
	maven { url = "https://maven.createmod.net/" }
	mavenCentral()
}

configurations {
	shade
}

dependencies {
	minecraft libs.mc
	implementation libs.fl
	implementation libs.fapi

	//modImplementation libs.sodium
	//modImplementation libs.flywheel
	//modImplementation libs.vanillin

	implementation libs.nettyIoUringClasses
	implementation variantOf(libs.nettyIoUringNative) { classifier "linux-x86_64" }
	implementation libs.zstd

	// This will *not* boot and you know it
	compileOnly(libs.bundles.worldedit) {
		exclude group: "it.unimi.dsi"
		exclude group: "com.google.code.gson"
		exclude group: "com.google.guava"
		exclude group: "org.apache.logging.log4j"
	}

	implementation "dev.gegy:player-roles-api:1.9.0-pre.1"

	shade(libs.nettyIoUringClasses) { transitive = false }
	shade(variantOf(libs.nettyIoUringNative) { classifier "linux-x86_64" }) { transitive = false }
	shade(libs.zstd) { transitive = false }

	include(implementation(annotationProcessor("com.github.bawnorton.mixinsquared:mixinsquared-fabric:0.3.3")))
}

processResources {
	final Map<String, String> meta = [
		version       : version,
		modId         : modId,
		modName       : modName,
		modDescription: modDescription,
		homepage      : "https://modrinth.com/mod/${slug}",
		issues        : "https://github.com/${user}/${slug}/issues",
		sources       : "https://github.com/${user}/${slug}",
		license       : license,
		authors       : authors.split(", ").join("\",\n    \""),
		contributors  : contributors.split(", ").join("\",\n    \""),
		members       : "${authors}. Contributions by ${contributors}",
		mc            : compatibleVersions.split(", ")[0],
		fl            : libs.versions.fl.get(),
		fapi          : libs.versions.fapi.get()
	]
	inputs.properties(meta)
	filesMatching("*.mod.json") { expand(meta) }
	filesMatching("META-INF/*mods.toml") { expand(meta) }
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = "UTF-8"
	it.options.release = 25
	it.options.compilerArgs += "-Xlint:deprecation,unchecked,rawtypes"
}

loom {
	accessWidenerPath = file("src/main/resources/fireblanket.accesswidener")
}

sourceSets {
	dummy {
		compileClasspath += sourceSets.main.compileClasspath
	}
	main {
		compileClasspath += sourceSets.dummy.output
	}
}

java {
	withSourcesJar()
	sourceCompatibility = JavaVersion.VERSION_25
	targetCompatibility = JavaVersion.VERSION_25
}

jar {
	from("LICENSE") {
		rename { "${it}_${base.archivesName}" }
	}

	configurations.shade.resolve().each {
		from(zipTree(it)) {
			exclude 'META-INF/MANIFEST.MF'
			exclude 'META-INF/INDEX.LIST'
			exclude 'META-INF/maven/**'
			// Unnecessary module-info.class
			exclude 'META-INF/versions/**'
			exclude 'META-INF/io.netty.versions.properties'
		}
	}
}

publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}
}

test {
	failOnNoDiscoveredTests = false
}