ViaFabric/build.gradle.kts at ver/26.x · ViaVersion/ViaFabric · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
plugins {
    id("java")
    id("maven-publish")
    id("org.ajoberstar.grgit") version "5.3.2"
    id("net.fabricmc.fabric-loom") version "1.15-SNAPSHOT"
    id("com.github.ben-manes.versions") version "0.53.0"
    id("me.modmuss50.mod-publish-plugin") version "1.1.0"
}

private val env = System.getenv()
group = "com.viaversion.fabric"
description = "Client-side and server-side ViaVersion implementation for Fabric"
version = "0.4.21+" + getRunNumber() + "-" + getBranch()

fun getRunNumber() = env["GITHUB_RUN_NUMBER"] ?: "unknown"

fun getBranch(): String {
    val branch = env["GITHUB_REF"] ?: grgit.branch.current().name ?: "unknown"
    return branch.substringAfterLast("/")
}

allprojects {
    apply(plugin = "java")
    apply(plugin = "maven-publish")
    apply(plugin = "net.fabricmc.fabric-loom")

    java {
        toolchain {
            languageVersion.set(JavaLanguageVersion.of(25))
            vendor.set(JvmVendorSpec.ADOPTIUM)
        }
        withSourcesJar()
    }

    tasks.withType<JavaCompile>().configureEach {
        options.release.set(25)
    }
    tasks.withType<JavaExec>().configureEach {
        javaLauncher.set(javaToolchains.launcherFor(java.toolchain))
    }

    version = rootProject.version
    group = rootProject.group

    repositories {
        mavenCentral()
        maven("https://repo.viaversion.com/")
        maven("https://maven.fabricmc.net/")
        maven("https://maven.terraformersmc.com/releases/")
        maven("https://maven.nucleoid.xyz/")
        maven("https://maven.parchmentmc.org")
    }

    dependencies {
        implementation("com.viaversion:viaversion:${rootProject.extra["viaver_version"]}") {
            // transitive = false because Guava is conflicting on runClient
            isTransitive = false
        }
        implementation("net.fabricmc:fabric-loader:${rootProject.extra["loader_version"]}")
    }

    tasks.processResources {
        filesMatching("fabric.mod.json") {
            expand(rootProject.properties)
        }
    }
}

subprojects {
    loom {
        runs {
            named("client") {
                client()
                ideConfigGenerated(true)
                runDir("run")
            }
            named("server") {
                server()
                ideConfigGenerated(true)
                runDir("run")
            }
        }
    }

    dependencies {
        implementation(project(":")) {
            exclude(group = "net.fabricmc", module = "fabric-loader") // prevent duplicate fabric-loader on run
        }
    }

    publishing {
        publications {
            create<MavenPublication>("mavenJava") {
                from(components["java"])
            }
        }
    }
}

publishing {
    publications {
        create<MavenPublication>("mavenJava") {
            from(components["java"])
        }
    }
}

dependencies {
    // dummy version
    minecraft("com.mojang:minecraft:26.1-snapshot-5")

    include("com.viaversion:viaversion:${rootProject.extra["viaver_version"]}")

    testImplementation("org.testng:testng:6.13.1")
}

loom {
    subprojects.forEach { subproject ->
        subproject.tasks.matching { it.name == "jar" }.configureEach {
            nestJars(tasks.jar, outputs.files)
        }
    }
}

tasks {
    test {
        useTestNG()
    }
    jar {
        subprojects.forEach { subproject ->
            dependsOn(subproject.tasks.named("jar"))
        }
    }
}

val mcReleases = rootProject.extra["publish_mc_versions"].toString().split(",")
    .map { it.trim() }

tasks.named("publishMods") {
    dependsOn(tasks.jar)
    subprojects.forEach { subproject ->
        dependsOn(subproject.tasks.named("jar"))
    }
}

publishMods {
    file = tasks.jar.get().archiveFile
    changelog = "A changelog can be found at https://github.com/ViaVersion/ViaFabric/commits"
    version = rootProject.version.toString()
    displayName = "[${getBranch()}] ViaFabric ${version.get()}"
    modLoaders.add("fabric")
    dryRun = providers.environmentVariable("CURSEFORGE_TOKEN").getOrNull() == null

    curseforge {
        accessToken = providers.environmentVariable("CURSEFORGE_TOKEN").orNull
        projectId = "391298"
        type = BETA // alpha is hidden by default

        javaVersions.add(JavaVersion.VERSION_25)

        minecraftVersions.addAll(mcReleases)
        requires("fabric-api")
        embeds("cotton-client-commands")
    }
    modrinth {
        accessToken = providers.environmentVariable("MODRINTH_TOKEN").orNull
        projectId = "YlKdE5VK"
        type = ALPHA
        minecraftVersions.addAll(mcReleases)
        requires("fabric-api")
        embeds("viaversion")
    }
}

defaultTasks("clean", "build")